identification division.
       program-id. client.

      * simple NetIPC example; connect, send, receive, shutdown

       data division.
       working-storage section.

       01  target-host   pic x(50) value "HP918.XYZ.HPCOM".
      *01  target-port   pic s9(4) comp value 32080.
       01  target-port   pic xx    value "}P".

       01  dest-desc     pic s9(9) comp.
       01  result        pic s9(9) comp.
       01  vc-desc       pic s9(9) comp.

       01  client-data   pic x(06) value "Client".
       01  server-data   pic x(06) value "??????".

       01  server-want   pic s9(9) comp value 6.
       01  server-have   pic s9(9) comp value 0.
       01  server-temp   pic s9(9) comp.
       01  server-offs   pic s9(9) comp.

       01  graceful      pic s9(9) comp value 16384.

       procedure division.

       main-body.
           display "calling ipcdest..."

           call intrinsic "ipcdest" using
             3,
             target-host, 15,
             4,
             target-port, 2,
             \\,
             \\,
             dest-desc,
             result

           display "result = " result

           if result <> 0 then
             stop run
           end-if

           display "calling ipcconnect..."

           call intrinsic "ipcconnect" using
             \\,
             dest-desc,
             \\,
             \\,
             vc-desc,
             result

           display "result = " result

           if result <> 0 then
             stop run
           end-if

           display "calling ipcrecv for conn..."

           call intrinsic "ipcrecv" using
             vc-desc,
             \\,
             \\,
             \\,
             \\,
             result

           display "result = " result

           if result <> 0 then
             stop run
           end-if

           display "calling ipcshutdown for dest..."

           call intrinsic "ipcshutdown" using
             dest-desc,
             \\,
             \\,
             result

           display "result = " result

           if result <> 0 then
             stop run
           end-if

           display "client request is " client-data

           display "calling ipcsend for data..."

           call intrinsic "ipcsend" using
             vc-desc,
             client-data, 6,
             \\,
             \\,
             result

           display "result = " result

           if result <> 0 then
             stop run
           end-if

           display "calling ipcrecv for data..."

           perform with test before until server-want = 0

             display "want = " server-want
             display "have = " server-have

             compute server-temp = server-want
             compute server-offs = server-have + 1

             call intrinsic "ipcrecv" using
               vc-desc,
               server-data(server-offs:server-temp),
               server-temp,
               \\,
               \\,
               result

             display "result = " result

             if result <> 0 then
               stop run
             end-if

             compute server-have = server-have + server-temp
             compute server-want = server-want - server-temp

           end-perform

           display "server response is " server-data

           display "calling ipcshutdown for conn..."

           call intrinsic "ipcshutdown" using
             vc-desc,
             graceful,
             \\,
             result

           display "result = " result

           stop run.

       end program client.