
<<
    Transact server for Java Telnet GUI client.
    Provides access to Music DB without JDBC.
    Quick & dirty prototype. Lars Appel, Jan/00.
>>

!sysdic(sysdic.dic)
!scope(da,"pw")
!version(v)

system tmusic, base=music("MGR",1,1);

 $$list:

  $albums:
  
  set(option) width=131;
  
  list albumcode: albumtitle: recordingco: daterecorded;

  output(serial) albums,
    list=(albumcode: daterecorded),
    nohead, nocount;

  reset(stack) list;


  $composers:
  
  set(option) width=131;
  
  list composername: birthplace: birth: death;

  output(serial) composers,
    list=(composername: death),
    nohead, nocount;

  reset(stack) list;


 $$review:

  $album:

  list(auto) albums;

  data(key) albumcode;

  format
    albumtitle,   line:
    medium,       line:
    albumcost,    line:
    recordingco,  line:
    daterecorded, line:
    mfgcode,      line:
    comment,      line;

  output albums, nohead, status;

  if status <> 0 then
    display "NOT FOUND";

  reset(stack) list;


  $composer:

  list(auto) composers;

  data(key) composername;

  format
    birth,      line:
    death,      line:
    birthplace, line:
    comment,    line;

  output composers, nohead, status;

  if status <> 0 then
    display "NOT FOUND";

  reset(stack) list;


 $$add:

  $album:

  list(auto) albums;

  data 
    albumcode: albumtitle: medium: albumcost: 
    recordingco: daterecorded: mfgcode: comment;

  put albums, status;

  if status <> 0 then
    display "ADD FAILED";
    
  reset(stack) list;


  $composer:

  list(auto) composers;

  data composername: birth: death: birthplace: comment;

  put composers, status;

  if status <> 0 then
    display "ADD FAILED";
    
  reset(stack) list;


 $$delete:

  $album:

  list(auto) albums;

  data(key) albumcode;

  delete albums, status;

  if status <> 0 then
    display "DELETE FAILED";

  reset(stack) list;


  $composer:

  list(auto) composers;

  data(key) composername;

  delete composers, status;

  if status <> 0 then
    display "DELETE FAILED";

  reset(stack) list;


 $$update:
 
  $album:

  list(auto) albums;

  data(key) albumcode;

  get albums, status;

  if status <> 0 then
    display "NOT FOUND"

  else
    do
      data(set) albumtitle: medium: albumcost: 
        recordingco: daterecorded: mfgcode: comment;

      update albums, status;
      
      if status <> 0 then
        display "UPDATE FAILED";
    doend;

  reset(stack) list;

 
  $composer:

  list(auto) composers;

  data(key) composername;

  get composers, status;

  if status <> 0 then
    display "NOT FOUND"

  else
    do
      data(set) birth: death: birthplace: comment;

      update composers, status;
      
      if status <> 0 then
        display "UPDATE FAILED";
    doend;

  reset(stack) list;


  end tmusic;